Files
imgui-java/build.gradle
T
dependabot[bot] 30502a324c build(deps): bump org.lwjgl:lwjgl-bom from 3.3.4 to 3.3.6 (#313)
Bumps [org.lwjgl:lwjgl-bom](https://github.com/LWJGL/lwjgl3) from 3.3.4 to 3.3.6.
- [Release notes](https://github.com/LWJGL/lwjgl3/releases)
- [Commits](https://github.com/LWJGL/lwjgl3/compare/3.3.4...3.3.6)

---
updated-dependencies:
- dependency-name: org.lwjgl:lwjgl-bom
  dependency-type: direct:production
  update-type: version-update:semver-patch
...

Signed-off-by: dependabot[bot] <support@github.com>
Co-authored-by: dependabot[bot] <49699333+dependabot[bot]@users.noreply.github.com>
2025-08-26 14:01:15 +03:00

70 lines
2.3 KiB
Groovy

import tool.generator.ast.task.GenerateAst
import java.text.SimpleDateFormat
ext {
lwjglVersion = '3.3.6'
}
allprojects {
group = 'imgui-java'
version = 'git describe --tags --always'.execute().text.trim().substring(1)
repositories {
mavenCentral()
}
tasks.withType(Jar).tap {
configureEach {
from(project.rootDir) {
include 'LICENSE'
into 'META-INF'
}
def jdkMetadata = tasks.withType(JavaCompile).find().javaCompiler.get().metadata
def buildJdk = "${jdkMetadata.javaRuntimeVersion} (${jdkMetadata.vendor})".toString()
manifest {
attributes (
'Implementation-Title': project.name,
'Implementation-Version': project.version,
'Build-Timestamp': new SimpleDateFormat("yyyy-MM-dd'T'HH:mm:ss.SSSZ").format(System.currentTimeMillis()),
'Build-Revision': 'git rev-parse HEAD'.execute().text.trim(),
'Build-Jdk': buildJdk,
'Source-Compatibility': tasks.withType(JavaCompile).find().sourceCompatibility,
'Target-Compatibility': tasks.withType(JavaCompile).find().targetCompatibility,
'Created-By': "Gradle ${gradle.gradleVersion} "
)
}
}
}
}
tasks.register('buildAll') { t ->
t.group = 'build'
t.description = 'Build all project sources.'
t.dependsOn ':imgui-app:shadowJar'
['app', 'binding', 'lwjgl3'].each { module ->
['build', 'sourcesJar', 'javadocJar'].each { task ->
t.dependsOn ":imgui-$module:$task"
}
}
}
tasks.register('generateAst', GenerateAst) {
headerFiles = [
file('include/imgui/imgui.h'),
file('include/imgui/imgui_internal.h'),
file('include/imgui/misc/freetype/imgui_freetype.h'),
file('include/ImGuiFileDialog/ImGuiFileDialog.h'),
file('include/imgui-knobs/imgui-knobs.h'),
file('include/imguizmo/ImGuizmo.h'),
file('include/imnodes/imnodes.h'),
file('include/implot/implot.h'),
file('include/imgui-node-editor/imgui_node_editor.h'),
file('include/ImGuiColorTextEdit/TextEditor.h'),
]
}