plugins {
    id 'java-library'
    id 'io.freefair.lombok' version '5.3.0'
    id 'checkstyle'
    id 'maven-publish'
    id 'signing'
}

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    api platform('org.lwjgl:lwjgl-bom:3.2.3')

    api 'org.lwjgl:lwjgl'
    api 'org.lwjgl:lwjgl-glfw'
    api 'org.lwjgl:lwjgl-opengl'

    ['natives-linux', 'natives-windows', 'natives-macos'].each {
        api "org.lwjgl:lwjgl::$it"
        api "org.lwjgl:lwjgl-glfw::$it"
        api "org.lwjgl:lwjgl-opengl::$it"
    }

    api project(':imgui-binding')
    api project(':imgui-lwjgl3')
}

jar {
    from('../bin') {
        include 'imgui-java64.dll'
        include 'libimgui-java64.so'
        include 'libimgui-java64.dylib'
        into 'io/imgui/java/native-bin/'
    }
}

task sourcesJar(type: Jar, dependsOn: classes) {
    archiveClassifier.set('sources')
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    archiveClassifier.set('javadoc')
    from javadoc.destinationDir
}

apply from: "$rootDir/publish.gradle"
configurePublishing('imgui-java-app', 'Application wrapper for Dear ImGui')